Fichier:Regression cercle gruntz pathologique anim.gif
Fichier d’origine (390 × 670 pixels, taille du fichier : 52 kio, type MIME : image/gif, en boucle, 38 trames, 19 s)
Ce fichier et sa description proviennent de Wikimedia Commons.
Description
DescriptionRegression cercle gruntz pathologique anim.gif |
English: Pathological case for the standard Gauss-Newton circle fitting: the point (3 ; 1) i close to the center of the model circle, which leads to a difficult convergence and a "weird looking" figure (although it is the correct total least squares model).
Français : Cas pathologique pour la régression circulaire utilisant la méthode de Gauss-Newton standard : le point (3 ; 1) est proche du centre du cercle modèle, cequi rend la convergence difficile, et donne une figure "bizarre" (bien qu'il s'agisse du modèle correct du point de vue des moindres carrés totaux). |
Date | |
Source |
Travail personnel Coope, Ian D., Circle fitting by Linear and Nonlinear Least Squares, in "Journal of Optimization Theory and Applications", vol. 76, No. 2, pp. 381-388, february 1993 Gruntz, D., Finding the Best Fit Circle, in "The MathWorks Newsletter", Vol. 1, p. 5, 1990 http://groups.google.com/group/sci.math.num-analysis/msg/f936dad6ff285069 |
Auteur | Cdang (Christophe Dang Ngoc Chan) |
Scilab source
This media was created with Scilab, a free open-source software. Here is a listing of the Scilab source used to create this file. |
Code source similaire à File:Regression cercle gruntz anim.gif, mais avec un point de plus, et une condition plus robuste sur k.
// **********
// Initialisation
// **********
clear;
// données (D. Gruntz + I. D. Coope)
X0 = [0.7, 3.3, 5.6, 7.5, 6.4, 4.4, 0.3, -1.1, 3];
Y0 = [4.0, 4.7, 4.0, 1.3, -1.1, -3.0, -2.5, 1.3, 0.5];
// Paramètres de Newton-Raphson
precision = 1e-7; // condition d'arrêt
itermax = 60; // idem
Ainit = [3,0, 1] // cercle initial
// **********
// fonctions
// **********
function [ACx, ACy, AC] = caracteristiques(Xexp, Yexp, A)
// calcule les caractéristiques du modèle
// par rapport aux points expérimentaux
// C(1) : xcentre (scalaire)
// C(2) : ycentre (scalaire)
// Xexp, Yexp : points mesurés (vecteur de nombres)
// ACx : vecteur de composante x des vecteurs AC>
// " y "
// AC : longueurs des vecteurs AC>
ACx = (A(1) - Xexp)';
ACy = (A(2) - Yexp)';
AC = ((ACx.^2 + ACy.^2).^(0.5));
endfunction
function [S] = residus(Xexp, Yexp, C)
// Xexp, Yexp : coordonnées des points expérimentaux (vecteurs)
// C : coordonnées du centre (vecteur)
[ACx, ACy, AC] = caracteristiques(Xexp, Yexp, C);
res = abs(C(3) - AC);
S = sum(res);
endfunction
function []=affichage(X, Y, A, R, k)
clf;
subplot(2,1,1)
plot2d(X, Y, style = -1) //, frameflag=4)
isoview(-1.5, 7.5, -3.5, 5.5);
xstring(-1.8, 5.3, 'C('+string(A(1))+' ; '+string(A(2))+') ; r = '+string(A(3)))
// modèle
plot(A(1), A(2), 'r+')
diametre = 2*A(3);
xarc(A(1) - A(3), A(2) + A(3),...
diametre, diametre,...
0, 360*64)
a = get('hdl'); // ellipse
a.foreground = 5; // couleur
subplot(2,1,2)
plot2d(R, rect=[1, 5, 38, 15])
xstring(0.5, 0.1, 'α = '+string(k)+' ; R = '+string(R($)))
// halt
endfunction
function [A, R]=regression_circulaire(Xexp, Yexp, Ainit, imax, epsilon)
// Xexp, Yexp : points expérimentaux
// A(1) : xcentre
// A(2) : ycentre
// A(3) : rayon
// Ainit : valeur initiale de A
// imax, epsilon : condition d'arrêt
i = 1;
k = 1;
A = Ainit';
dA = [1 1 1]';
drapeau = %t; // pour la 1re itération
R(1) = residus(Xexp, Yexp, A')
affichage(Xexp, Yexp, Ainit, R, 1)
disp('i = '+string(i)+' ; k = 1 ; R = '+string(R(i)))
nom = 'cercle_gruntz_pathologique'+string(i)+'.png';
xs2png(0,nom)
while drapeau & (i <= imax)
i = i+1;
[ACx, ACy, AC] = caracteristiques(Xexp, Yexp, A);
J = [ACx./AC, ACy./AC, -ones(ACx)]; // matrice des vecteurs unité
f = -(AC - A(3)*(ones(Xexp))');
dA = J\f;
drapeau2 = %t // pour une 1re exécution
while drapeau2 & (k>=0.1) // teste la divergence sur 1 étape
A = A + k*dA;
R(i) = residus(Xexp, Yexp, A')
drapeau2 = (R(i) >= R(i-1)) // vrai si diverge
if drapeau2 then k = k*0.75; // atténue si diverge
k0 = k; // pour affichage de la valeur
else k0 = k; // pour affichage de la valeur
k = (1 + k)/2; // réduit l'atténuation si converge
end
end
if k < 0.1 then
k = 0.1;
k0 = k;
end
drapeau = (abs(R(i) - R(i-1)) > epsilon)
disp('i = '+string(i)+' ; k = '+string(k0)+' ; R = '+string(R(i)))
affichage(Xexp, Yexp, A', R, k0)
nom = 'cercle_gruntz_pathologique'+string(i)+'.png';
xs2png(0,nom)
end
endfunction
// **********
// programme principal
// **********
// lecture des données
// Xdef, Ydef : vecteurs ligne
Xdef = X0;
Ydef = Y0;
fenetre = scf(0); // création de la fenêtre graphique
fenetre.figure_size = [400,800];
// regression
[Aopt, res] = regression_circulaire(Xdef, Ydef, Ainit, itermax, precision)
centre = Aopt(1:2);
rayon = Aopt(3);
R = res($);
print(%io(2), centre)
print(%io(2), rayon)
print(%io(2), R)
Conditions d’utilisation
Vous avez la permission de copier, distribuer et modifier ce document selon les termes de la GNU Free Documentation License version 1.2 ou toute version ultérieure publiée par la Free Software Foundation, sans sections inaltérables, sans texte de première page de couverture et sans texte de dernière page de couverture. Un exemplaire de la licence est inclus dans la section intitulée GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
- Vous êtes libre :
- de partager – de copier, distribuer et transmettre cette œuvre
- d’adapter – de modifier cette œuvre
- Sous les conditions suivantes :
- paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
- partage à l’identique – Si vous modifiez, transformez, ou vous basez sur cette œuvre, vous devez distribuer votre contribution sous la même licence ou une licence compatible avec celle de l’original.
Éléments décrits dans ce fichier
dépeint
Valeur sans élément de Wikidata
12 décembre 2012
Historique du fichier
Cliquer sur une date et heure pour voir le fichier tel qu'il était à ce moment-là.
Date et heure | Vignette | Dimensions | Utilisateur | Commentaire | |
---|---|---|---|---|---|
actuel | 12 décembre 2012 à 15:59 | 390 × 670 (52 kio) | Cdang | {{Information |Description ={{en|1=Pathological case for the standard Gauss-Newton circle fitting: the point (3 ; 1) i close to the center of the model circle, which leads to a difficult convergence and a "weird looking" figure (although it is the c... |
Utilisation du fichier
La page suivante utilise ce fichier :
Métadonnées
Ce fichier contient des informations supplémentaires, probablement ajoutées par l'appareil photo numérique ou le numériseur utilisé pour le créer.
Si le fichier a été modifié depuis son état original, certains détails peuvent ne pas refléter entièrement l'image modifiée.
Commentaire de fichier GIF | Created with GIMP |
---|