set terminal svg dashed size 800,500
set output 'time-saving-bias.svg'
set object 1 rectangle from screen 0,0 to screen 1,1 fillcolor rgb"white" behind

#test
#set output

set xrange [0:70]
set yrange [0:70]

set ytics 10
set ytics add ("12" 12)

set xlabel "speed v [mph]"
set ylabel "time [min.]"

f(x) = 60 * (10 / x)
g(x) = 60 * (10 / (x + 10))

# draw guide lines:
set arrow 1 from 0,30 to 20,30 nohead lt 3
set arrow 2 from 0,20 to 20,20 nohead lt 3
set arrow 3 from 0,12 to 50,12 nohead lt 3
set arrow 4 from 0,10 to 50,10 nohead lt 3
set arrow 5 from 20,0 to 20,30 nohead lt 3
set arrow 6 from 50,0 to 50,12 nohead lt 3

# draw arrows:
set arrow 7 from 1.5,20 to 1.5,30 heads lt 1 linecolor rgb "blue" size 0.7, 30
set arrow 8 from 1.5,10 to 1.5,12 heads lt 1 linecolor rgb "blue" size 0.7, 30

# labels:
set label "savings: 10 min." at 2.2,25 textcolor rgb "blue"
set label "savings: 2 min." at 2.2,8 textcolor rgb "blue"

plot f(x) title 'time required when travelling with speed v' with lines linestyle 1, \
     g(x) title 'time required when travelling with speed v + 10' with lines linestyle 1 linecolor rgb "green"